Determine Result Table Based on Rules

let
  Source = Excel.CurrentWorkbook(){[Name = "Table1"]}[Content], 
  Table = Table.FromList(
    List.Transform(
      List.Skip(
        List.Accumulate(
          {0 .. List.Count(List.Distinct(Source[Process])) - 1}, 
          {""}, 
          (s, c) => s & {List.Last(s) & ", " & List.Distinct(List.Sort(Source[Process])){c}}
        )
      ), 
      each Text.Trim(Text.TrimStart(_, ","))
    ), 
    Splitter.SplitByNothing(), 
    null, 
    null, 
    ExtraValues.Error
  ), 
  Process = Table.Group(Source, {"User"}, {{"Count", each Text.Combine([Process], ", ")}})[Count], 
  Cuenta = Table.AddColumn(
    Table, 
    "Custom", 
    (X) => List.Count(List.Select(Process, each Text.Contains(_, X[Column1])))
  ), 
  Sol = Table.SelectRows(Cuenta, each ([Custom] > 0))
in
  Sol

let
  Fonte = Tabela1, 
  gp1 = Table.Group(
    Fonte, 
    {"User"}, 
    {
      {
        "Contagem", 
        each [
          a = Table.AddIndexColumn(_, "Rank", 1, 1), 
          b = Table.AddColumn(
            a, 
            "Seq", 
            each Number.From(List.RemoveFirstN(Text.Split([Process], " "), 1){0})
          ), 
          c = Table.AddColumn(b, "Comp", each if [Rank] = [Seq] then true else null)
        ][c]
      }
    }
  )[[Contagem]], 
  exp1 = Table.ExpandTableColumn(gp1, "Contagem", Table.ColumnNames(gp1[Contagem]{0})), 
  fil = Table.SelectRows(exp1, each ([Comp] = true)), 
  gp2 = Table.Group(
    fil, 
    {"Rank"}, 
    {
      {"tab", each _}, 
      {"Contagem", each Table.RowCount(_)}, 
      {"Seq1", each Table.AddIndexColumn(_, "Sequec", 1, 1)}
    }
  )[[Contagem], [Seq1]], 
  exp2 = Table.ExpandTableColumn(gp2, "Seq1", {"Process", "Sequec"}, {"Process", "Sequec"}), 
  gp3 = Table.Group(exp2, {"Sequec"}, {{"Contagem1", each _[Process]}, {"Count", each _[Contagem]}}), 
  exp3 = Table.TransformColumns(
    gp3, 
    {"Contagem1", each Text.Combine(List.Transform(_, Text.From), ","), type text}
  ), 
  clas = Table.Sort(exp3, {{"Sequec", Order.Descending}}), 
  Result = Table.Distinct(
    Table.AddColumn(
      clas, 
      "Personalizar", 
      each if List.Contains([Count], [Sequec]) = true then [Sequec] else List.Min([Count])
    )[[Contagem1], [Personalizar]]
  )
in
  Result

let
  Source = Excel.CurrentWorkbook(){[Name = "Process"]}[Content], 
  Grouped = Table.Group(
    Source, 
    {"User"}, 
    {
      {
        "Process", 
        each [
          a = [Process], 
          b = List.Select(a, each try _ = a{Number.From(Text.End(_, 1)) - 1} otherwise null), 
          c = Text.Combine(b, ", ")
        ][c]
      }
    }
  )[[Process]], 
  Filtered = Table.SelectRows(Grouped, each ([Process] <> "")), 
  Duplicated = Table.DuplicateColumn(Filtered, "Process", "Process Group"), 
  Split = Table.ExpandListColumn(
    Table.TransformColumns(
      Duplicated, 
      {
        {
          "Process", 
          Splitter.SplitTextByDelimiter(", ", QuoteStyle.Csv), 
          let
            itemType = (type nullable text) meta [Serialized.Text = true]
          in
            type {itemType}
        }
      }
    ), 
    "Process"
  ), 
  Grouped1 = Table.Group(
    Split, 
    {"Process"}, 
    {
      {"Process Group", each List.Min([Process Group])}, 
      {"Count", each Table.RowCount(_), Int64.Type}
    }
  )[[Process Group], [Count]]
in
  Grouped1

let
  Source = Excel.CurrentWorkbook(){[Name = "Table1"]}[Content], 
  Lists = 
    let
      l = List.Buffer(List.Distinct(Source[Process]))
    in
      List.Transform(List.Positions(l), each List.FirstN(l, _ + 1)), 
  Grouped = Table.Group(
    Source, 
    {"User"}, 
    {
      {
        "all", 
        (a) =>
          List.Transform(
            Lists, 
            (b) => [
              Process Group = Text.Combine(b, ", "), 
              Count         = Number.From(List.Intersect({b, a[Process]}) = b)
            ]
          )
      }
    }
  ), 
  Counts = Table.Group(
    Table.FromRecords(List.Combine(Grouped[all])), 
    {"Process Group"}, 
    {{"Count", each List.Sum([Count])}}
  )
in
  Counts

=LET(a,A2:A16,b,B2:B16,m,SCAN(,b,LAMBDA(a,v,IF(a