List Local Temperature Peaks

let
  Source = Table.AddIndexColumn(
    Table.AddIndexColumn(
      Table.TransformColumnTypes(TemperatureRaw, {{"Date", Date.Type}, {"Temperature", Int64.Type}}), 
      "IndexB", 
      - 1, 
      1
    ), 
    "IndexF", 
    1, 
    1
  ), 
  AddBack = Table.AddColumn(
    Source, 
    "Back", 
    each try Table.Column(Source, "Temperature"){[IndexB]} otherwise null
  ), 
  AddFwd = Table.AddColumn(
    AddBack, 
    "Fwd", 
    each try Table.Column(AddBack, "Temperature"){[IndexF]} otherwise null
  ), 
  FilterTwice = Table.SelectRows(
    Table.SelectRows(AddFwd, each ([Back] <> null) and ([Fwd] <> null)), 
    each ([Temperature] > [Back]) and ([Temperature] > [Fwd])
  ), 
  Clean = Table.RenameColumns(Table.SelectColumns(FilterTwice, "Date"), {"Date", "Expected Answer"})
in
  Clean

let
  Source = PeakTemperatureDATA, 
  #"Filtered Rows" = Table.SelectRows(
    Source, 
    each 
      let
        temp = Source[Temperature], 
        prev = {null} & List.RemoveLastN(temp, 1), 
        next = List.RemoveFirstN(temp, 1), 
        row  = List.PositionOf(Source[Date], [Date])
      in
        try temp{row} > prev{row} and temp{row} > next{row} otherwise false
  )[[Date]]
in
  #"Filtered Rows"

let
  Source = DataSource, 
  DateList = List.Buffer(DataSource[Date]), 
  Flag = Table.AddColumn(
    Source, 
    "Flag", 
    (CurrentRow) =>
      let
        CurrentDate = CurrentRow[Date], 
        PriorDate = List.Max(List.Select(DateList, each _ < CurrentDate)), 
        NextDate = List.Min(List.Select(DateList, each _ > CurrentDate)), 
        Check = DataSource{[Date = CurrentDate]}[Temperature]
          > DataSource{[Date = PriorDate]}[Temperature]
            and DataSource{[Date = CurrentDate]}[Temperature]
          > DataSource{[Date = NextDate]}[Temperature], 
        Status = if PriorDate is null or NextDate is null then null else Check
      in
        Status
  ), 
  Result = Table.SelectColumns(Table.SelectRows(Flag, each [Flag] = true), "Date")
in
  Result

let
 Source = Table.Buffer ( DataSource ),
 NewTable = hashtag#table( type table [Date = date], {}),
 Index = {1..Table.RowCount ( Source ) - 1},
 DatesToKeep = 
 List.Accumulate ( 
 Index,
 NewTable,
 (State, Current) =>
 Table.InsertRows ( 
 State,
 Table.RowCount ( State),
 {
 let
 PriorDate = Source[Temperature]{Current-1},
 CurrentDate = Source[Temperature]{Current},
 NextDate = Source[Temperature]{Current+1},
 Check = 
 if CurrentDate > PriorDate and CurrentDate > NextDate 
 then Source[Date]{Current} 
 else null
 in
 [Date = Check]
 }
 )
 ),
 Result = 
 Table.SelectRows ( DatesToKeep, each [Date] <> null )
in
 Result


                    
                  
          

let
  Source = Data, 
  Result = Table.SelectRows(
    Table.AddColumn(
      Source, 
      "Custom", 
      each 
        let
          _row = Table.PositionOf(Source, _)
        in
          try
            
              if Source{_row}[Temperature]
                > Source{_row - 1}[Temperature] and Source{_row}[Temperature]
                > Source{_row + 1}[Temperature]
              then
                true
              else
                false
          otherwise
            false
    ), 
    each ([Custom] = true)
  )[Date]
in
  Result

let
  Source = Table.TransformColumnTypes(Data, {{"Date", type date}, {"Temperature", Int64.Type}}), 
  Index = Table.AddIndexColumn(Source, "Index", 0, 1, Int64.Type), 
  AddPrevRow = Table.AddColumn(
    Index, 
    "PrevRow", 
    each try Index[Temperature]{[Index] - 1} otherwise null
  ), 
  AddNextRow = Table.AddColumn(
    AddPrevRow, 
    "Next Row", 
    each try Index[Temperature]{[Index] + 1} otherwise null
  ), 
  CheckCondition = Table.SelectColumns(
    Table.SelectRows(
      Table.AddColumn(
        AddNextRow, 
        "Custom", 
        each 
          if [Temperature] > [PrevRow] and [Temperature] > [Next Row] then
            [Temperature]
          else
            null
      ), 
      each [Custom] <> null
    ), 
    "Date"
  )
in
  CheckCondition

let
 Source = YourData,
 ModifType= Table.TransformColumnTypes(Source,{{"Date", type date}, {"Temperature", Int64.Type}},"en-us"),
 Filtered =
 Table.SelectRows(
 ModifType,
 each 
 let 
 currDate = [Date],
 prevTemp = Table.SelectRows( ModifType , each [Date] = Date.AddDays(currDate , -1) )[Temperature]{0} ?, 
 nextTemp = Table.SelectRows( ModifType , each [Date] = Date.AddDays(currDate , 1) )[Temperature]{0} ?,
 Greater = [Temperature] > prevTemp and [Temperature] > nextTemp
 in Greater
 )
in
 Filtered

Thanks for the challenge !


                    
                  
          

let
 Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
 Merge = Table.NestedJoin(Table.ExpandListColumn(Table.AddColumn(Source, "Custom", each {Date.AddDays([Date],-1),Date.AddDays([Date],1)}), "Custom"), {"Custom"}, #"Source", {"Date"}, "Dates", JoinKind.LeftOuter),
 Temp = Table.ExpandTableColumn(Merge, "Dates", {"Temperature"}, {"Temp to Check"}),
 Check = Table.AddColumn(Temp, "Check", each try if [Temperature]>[Temp to Check] then 1 else 0 otherwise 0),
 Select = Table.SelectColumns(Table.SelectRows(Table.Group(Check, {"Date"}, {{"Count", each List.Sum([Check]), type number}}), each ([Count] = 2)),{"Date"}),
 Date = Table.TransformColumnTypes(Select,{{"Date", type date}})
in
 Date

On row level it could be done with Index Column or Table.PositionOf.


                    
                  
          

let
  Source = Excel.CurrentWorkbook(){[Name = "Table1"]}[Content], 
  Change_Types = Table.TransformColumnTypes(
    Source, 
    {{"Date", type date}, {"Temperature", Int64.Type}}
  ), 
  Index = Table.AddIndexColumn(Change_Types, "Index", 0, 1, Int64.Type), 
  Add_Previous_Row = Table.AddColumn(
    Index, 
    "Previous Row", 
    each try Index[Temperature]{[Index] - 1} otherwise 0
  ), 
  Add_Next_Row = Table.AddColumn(
    Add_Previous_Row, 
    "Next Row", 
    each try Index[Temperature]{[Index] + 1} otherwise 0
  ), 
  Is_Higher = Table.AddColumn(
    Add_Next_Row, 
    "Higher then Previous and Next", 
    each if [Temperature] > [Previous Row] and [Temperature] > [Next Row] then true else false
  ), 
  Filter_higher = Table.SelectRows(Is_Higher, each ([Higher then Previous and Next] = true)), 
  Remove_Other_Columns = Table.SelectColumns(Filter_higher, {"Date"})
in
  Remove_Other_Columns

let
  Source = Table.FromRows(
    Json.Document(
      Binary.Decompress(
        Binary.FromText(
          "Zc9JCgAhDETRu2StmMGpzyLe/xotxEVJto8Q6q9FLIVnUValREI7HVIgczKgXN1qPGuReqQBdH9N/D/cvmjCaM0NC7qThiixSDFAMCBfw4I7AwvydHsS1O1JONv2Dw==", 
          BinaryEncoding.Base64
        ), 
        Compression.Deflate
      )
    ), 
    let
      _t = ((type nullable text) meta [Serialized.Text = true])
    in
      type table [Date = _t, Temperature = _t]
  ), 
  #"Changed Type" = Table.TransformColumnTypes(
    Source, 
    {{"Date", type date}, {"Temperature", Int64.Type}}
  ), 
  AddedIndex = Table.AddIndexColumn(#"Changed Type", "Index", 0, 1, Int64.Type), 
  PreviousDay = Table.AddColumn(
    AddedIndex, 
    "PreviousDay", 
    each try AddedIndex[Temperature]{[Index] - 1} otherwise null
  ), 
  NextDay = Table.AddColumn(
    PreviousDay, 
    "NextDay", 
    each try PreviousDay[Temperature]{[Index] + 1} otherwise null
  ), 
  TempCheck = Table.AddColumn(
    NextDay, 
    "HigherInd", 
    each if [Temperature] > [PreviousDay] and [Temperature] > [NextDay] then 1 else 0
  ), 
  OnlyHigherRows = Table.SelectRows(TempCheck, each ([HigherInd] = 1)), 
  OnlyDate = Table.SelectColumns(OnlyHigherRows, {"Date"})
in
  OnlyDate