List Longest Words in Sentence

let
  Source = Excel.CurrentWorkbook(){[Name = "data"]}[Content], 
  Result = Table.AddColumn(
    Source, 
    "Split", 
    each Text.Combine(
      [
        a = Text.Split([Sentence], " "), 
        b = List.Max(List.Transform(a, (f) => Text.Length(f))), 
        c = List.Select(a, (f) => Text.Length(f) = b)
      ][c], 
      ", "
    )
  )
in
  Result

Welcome to GitHub!!! Great code and it worked like a charm.
1st is each _ and 2nd is List.Transform(_
Group2 = Table.Group(Filtro, {"Índice"}, {{"Tabela", each _, type table [Índice=number, Sentence=nullable text, Personalizar.1=nullable number, Personalizar=number, Personalizar.2=number]}}),
Result = Table.TransformColumns(Tab2, {"Sentence", each Text.Combine(List.Transform(_, Text.From), ","), type text})[[Sentence]]
                    
                  

let
  Source = Data, 
  #"Expected OutPut" = Table.AddColumn(
    Data, 
    "Expected", 
    each 
      let
        _Max = List.First(
          List.Sort(
            List.Transform(Text.Split([Sentence], " "), each Text.Length(_)), 
            Order.Descending
          )
        )
      in
        Text.Proper(
          Text.Combine(List.Select(Text.Split([Sentence], " "), each Text.Length(_) = _Max), ", ")
        )
  )
in
  #"Expected OutPut"

let
  Source = Excel.CurrentWorkbook(){[Name = "range"]}[Content], 
  #"Promoted Headers" = Table.PromoteHeaders(Source, [PromoteAllScalars = true]), 
  Result = Table.FromColumns(
    {
      List.Transform(
        #"Promoted Headers"[Sentence], 
        each [
          w = Text.Split(Text.Proper(_), " "), 
          m = List.Max(List.Transform(w, each Text.Length(_))), 
          a = List.Select(w, each Text.Length(_) = m), 
          t = Text.Combine(a, ", ")
        ][t]
      )
    }, 
    {"Result"}
  )
in
  Result

let
  Source = Excel.CurrentWorkbook(){[Name = "Table1"]}[Content], 
  Result = Table.AddColumn(
    Source, 
    "Result", 
    each [
      l   = Text.Split([Sentence], " "), 
      len = List.Transform(l, Text.Length), 
      i   = List.PositionOf(len, List.Max(len), Occurrence.All), 
      r   = Text.Combine(List.Transform(i, each Text.Proper(l{_})), ", ")
    ][r]
  )
in
  Result

let
  Source = Excel.CurrentWorkbook(){[Name = "Table1"]}[Content], 
  #"Index" = Table.AddIndexColumn(Source, "Index", 1, 1, Int64.Type), 
  #"Split Column" = Table.SplitColumn(
    #"Index", 
    "Sentence", 
    Splitter.SplitTextByDelimiter(" ", QuoteStyle.Csv), 
    {"Sentence.1", "Sentence.2", "Sentence.3", "Sentence.4"}
  ), 
  #"Unpivot" = Table.UnpivotOtherColumns(#"Split Column", {"Index"}, "Attribute", "Answer"), 
  #"Added Custom" = Table.AddColumn(#"Unpivot", "Length", each Text.Length([Answer])), 
  #"Grouped Rows" = Table.Group(
    #"Added Custom", 
    {"Index", "Length"}, 
    {
      {
        "Data", 
        each _, 
        type table [Index = number, Attribute = text, Answer = text, Length = number]
      }, 
      {"Answer", each Text.Combine([Answer], ", "), type text}
    }
  ), 
  #"Sort" = Table.Sort(#"Grouped Rows", {{"Length", Order.Descending}}), 
  #"Index2" = Table.AddIndexColumn(#"Sort", "Index.1", 1, 1, Int64.Type), 
  #"Table Distinct" = Table.Distinct(#"Index2", {"Index"}), 
  #"Sort2" = Table.Sort(#"Table Distinct", {{"Index", Order.Ascending}}), 
  #"Capital Words" = Table.TransformColumns(#"Sort2", {{"Answer", Text.Proper, type text}}), 
  #"Select Columns" = Table.SelectColumns(#"Capital Words", {"Answer"})
in
  #"Select Columns"

let
  words       = List.Transform(Text.Split([Sentence], " "), each Text.Proper(_)), 
  maxlength   = List.Max(List.Transform(words, each Text.Length(_))), 
  longestword = List.Select(words, each Text.Length(_) = maxlength)
in
  Text.Combine(longestword, ", ")