Home » Generate Logical Grid Pattern

Generate Logical Grid Pattern

Provide a formula to generate the given grid. This time, apart from making a formula, you also need to work out the logic to understand what this grid is. Hence, double challenge this time. There is a hidden sheet named Clue in this workbook. If you need, you can unhide the sheet to see what logic to follow to generate this grid.

📌 Challenge Details and Links
ExcelBI Excel Challenge Number: 55
Challenge Difficulty: ⭐️⭐️
📥Download Sample File
📥Link to the solutions on LinkedIn

Solving the challenge of Generate Logical Grid Pattern with Power Query

Power Query solution 1 for Generate Logical Grid Pattern, proposed by Aditya Kumar Darak 🇮🇳: 
let
  Generate = List.TransformMany(
    {1 .. 10}, 
    (x) => {1 .. 10}, 
    (x, y) => List.Sum(List.Transform(Text.ToList(Text.From(x * y)), Number.From))
  ), 
  Split = List.Split(Generate, 10), 
  Return = Table.FromColumns(Split)
in
  Return
Power Query solution 2 for Generate Logical Grid Pattern, proposed by Matthias Friedmann: 
let
  Source = Table.FromColumns(
    List.Transform(
      {1 .. 10}, 
      each 
        let
          a = _
        in
          List.Transform(
            {1 .. 10}, 
            each Number.Mod(a * _, 10)
              + (
                if Number.IntegerDivide(a * _, 10) < 10 then Number.IntegerDivide(a * _, 10) else 1
              )
          )
    )
  )
in
  Source

Solving the challenge of Generate Logical Grid Pattern with Excel

Excel solution 1 for Generate Logical Grid Pattern, proposed by Rick Rothstein: 
=LET(x,ROW(1:10)*COLUMN(A:J)&0,LEFT(x)+MID(x,2,1))
Excel solution 2 for Generate Logical Grid Pattern, proposed by John V.: 
=MAKEARRAY(10,10,LAMBDA(x,y,-SUM(-MID(x*y&0,{1;2},1))))
Excel solution 3 for Generate Logical Grid Pattern, proposed by محمد حلمي: 
=LET(
    a,
    MOD(
        COLUMN(
            A2:J2
        )*ROW(
            1:10
        ),
        99
    ),
    
    MOD(
        a,
        10
    )+INT(
        a/10
    )
)
Excel solution 4 for Generate Logical Grid Pattern, proposed by محمد حلمي: 
=LET(
    a,
    COLUMN(
        A2:J2
    )*ROW(
        1:10
    ),
    
    IF(
        a=100,
        1,
        MOD(
            a,
            10
        )+INT(
            a/10
        )
    )
)
Excel solution 5 for Generate Logical Grid Pattern, proposed by Julian Poeltl: 
=MAP(SEQUENCE(,10)*SEQUENCE(10),LAMBDA(A,SUM(--MID(A,SEQUENCE(LEN(A)),1))))
Excel solution 6 for Generate Logical Grid Pattern, proposed by Aditya Kumar Darak 🇮🇳: 
= MAKEARRAY(10, 10, LAMBDA(r, c, LET(_calc, r * c, SUM(--MID(_calc, SEQUENCE(LEN(_calc)), 1)))))
Excel solution 7 for Generate Logical Grid Pattern, proposed by Timothée BLIOT: 
=10,RIGHT(a*b,1)))))
Excel solution 8 for Generate Logical Grid Pattern, proposed by Charles Roldan: 
=
LAMBDA(x, MAP(
LAMBDA(y, y*TOROW(y))(SEQUENCE(x)), 
LAMBDA(z, SUM(--MID(z, SEQUENCE(LEN(z)), 1)))
))(10)
Excel solution 9 for Generate Logical Grid Pattern, proposed by Stefan Olsson: 
=MAKEARRAY(
    10,
    10,
    LAMBDA(
        _r,
        _c,
        SUM(
            SPLIT(
                REGEXREPLACE(
                    _r*_c&"",
                    "",
                    "|"
                ),
                "|"
            )
        )
    )
)
Excel solution 10 for Generate Logical Grid Pattern, proposed by Viswanathan M B: 
=Mod(Sequence(10)*Sequence(1,10)-1, 9)
Excel solution 11 for Generate Logical Grid Pattern, proposed by Viswanathan M B: 
=LET(a,
     SEQUENCE(
         10
     )*SEQUENCE(
         1,
         10
     ),
    
 b,
     LEN(
         a
     ),
    
 c,
     10^(b-1),
    
 Mod(
     a,
     c
 )+INT(
     a/c
 ))

It will need tweaking for 11*11 grids (and may eventually involve recursion/iteration)
Excel solution 12 for Generate Logical Grid Pattern, proposed by Ibrahim Sadiq: 
=LET(
    a,
    SEQUENCE(
        10
    )*SEQUENCE(
        ,
        10
    ),
    b,
    MOD(
        a,
         10
    )+QUOTIENT(
        a,
        10
    ),
     IF(
         b=10,
         1,
          b
     )
)
Excel solution 13 for Generate Logical Grid Pattern, proposed by Charalampos Dimitrakopoulos: 
=MAP(
    SEQUENCE(
        10
    )*SEQUENCE(
        ,
        10
    ),
     LAMBDA(
         x,
          SUM(
              --MID(
                  x,
                   SEQUENCE(
                       LEN(
                           x
                       )
                   ),
                   1
              )
          )
     )
)

&&&

Leave a Reply