List Numbers After Last Eight

let
  Source   = Excel.CurrentWorkbook(){[Name = "data"]}[Content], 
  Position = List.PositionOf(Source[Number], 8, Occurrence.Last), 
  Skipped  = Table.Skip(Source, Position), 
  Result   = Table.SelectRows(Skipped, each [Number] > 8)
in
  Result

let
  Fonte = Excel.CurrentWorkbook(){[Name = "Tabela7"]}[Content], 
  Result = Table.SelectRows(
    Table.AddIndexColumn(
      Table.AddColumn(Fonte, "Lista", each List.PositionOf(Fonte[Number], 8, Occurrence.Last)), 
      "Indice", 
      0, 
      1, 
      Int64.Type
    ), 
    each [Indice] > [Lista] and [Number] > 8
  )[[Number]]
in
  Result

let
  Source = Table.RenameColumns(
    Table.AddIndexColumn(
      Table.TransformColumnTypes(EightsRaw, {"Number", Int64.Type}), 
      "Index", 
      1, 
      1
    ), 
    {"Number", "ExpectedAnswer"}
  ), 
  Max8 = Table.AddColumn(Source, "Position", each if [ExpectedAnswer] = 8 then [Index] else null), 
  Cleanup = Table.SelectRows(
    Table.SelectColumns(Table.Skip(Max8, List.Max(Max8[Position])), "ExpectedAnswer"), 
    each [ExpectedAnswer] > 8
  )
in
  Cleanup

let
  Source           = Excel.CurrentWorkbook(){[Name = "greater8"]}[Content], 
  RowsAfterLast8   = Table.LastN(Source, List.PositionOf(List.Reverse(Source[Number]), 8)), 
  #"Filtered Rows" = Table.SelectRows(RowsAfterLast8, each [Number] > 8)
in
  #"Filtered Rows"

List.Reverse vs. Occurrence.Last, odd that I care about it.

let
  Source = Data, 
  Output = List.Select(
    List.Skip(Source[Number], List.PositionOf(Source[Number], 8, Occurrence.Last)), 
    each _ > 8
  )
in
  Output

let
  Source = Excel.CurrentWorkbook(){[Name = "Table1"]}[Content], 
  RemovedTopRows = Table.Skip(
    Source, 
    List.Last(List.PositionOf(Source[Number], 8, Occurrence.All)) + 1
  ), 
  FilteredRows = Table.SelectRows(RemovedTopRows, each [Number] > 8)
in
  FilteredRows

let
 Source = Excel.CurrentWorkbook(){[Name="range"]}[Content],
 #"Promoted Headers" = Table.PromoteHeaders(Source, [PromoteAllScalars=true]),

 tbl = #"Promoted Headers",
 empty = Table.FromValue( "no such numbers", [DefaultColumnName = "Oops..."] ),
 magicNumber = 8,

 Answer = 
 if Table.RowCount ( Table.SelectRows(tbl, each [Number] = magicNumber) ) = 0 or
 Table.Last( tbl )[Number] = magicNumber
 then empty
 else Table.LastN(
 Table.SelectRows( tbl,
 each [Number] >= magicNumber ),
 each [Number] > magicNumber )
in
 Answer

--------------------------
--- Simplified variant----
let
 Source = Excel.CurrentWorkbook(){[Name="range"]}[Content],
 #"Promoted Headers" = Table.PromoteHeaders(Source, [PromoteAllScalars=true]),

 Answer = Table.LastN(
 Table.SelectRows(
 #"Promoted Headers",
 each [Number] >= 8),
 each [Number] > 8 )
in
 Answer


                    
                  
          

let
 Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
 Type = Table.TransformColumnTypes(Source,{{"Number", Int64.Type}}),
 Index = Table.AddIndexColumn(Type, "Index", 0, 1, Int64.Type),
 Grouped = Table.Group(Index, {"Number"}, {{"Row", each List.Max([Index]), type number}}),
 Filtered = Table.SelectRows(Grouped, each [Number] = 8)
in
 Filtered

let
 Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
 Type = Table.TransformColumnTypes(Source,{{"Number", Int64.Type}}),
 Index = Table.AddIndexColumn(Type, "Index", 0, 1, Int64.Type),
 Queries = Table.NestedJoin(Index, {"Index"}, #"Look Up Row", {"Row"}, "Look Up Row", JoinKind.LeftOuter),
 Expand = Table.ExpandTableColumn(Queries, "Look Up Row", {"Row"}, {"Row"}),
 Fill = Table.FillDown(Expand,{"Row"}),
 Filter = Table.SelectRows(Fill, each ([Row] = 11)),
 #"Filter>8" = Table.SelectRows(Filter, each [Number] > 8),
 Select = Table.SelectColumns(#"Filter>8",{"Number"})
in
 Select


                    
                  
          

let
  IronMan = Data, 
  EndGame = Table.SelectRows(
    Table.RemoveFirstN(IronMan, List.PositionOf(IronMan[Number], 8, Occurrence.Last)), 
    each [Number] > 8
  )
in
  EndGame

let
  Source = Datasource, 
  #"Added Index" = Table.AddIndexColumn(Source, "Index", 0, 1, Int64.Type), 
  #"Grouped Rows" = Table.Group(
    #"Added Index", 
    {"Number"}, 
    {{"Count", each _, type table [Number = nullable number, Index = number]}}
  ), 
  #"Added Custom" = Table.AddColumn(
    #"Grouped Rows", 
    "Custom", 
    each Table.AddIndexColumn([Count], "IndexNb", 0)
  ), 
  #"Removed Other Columns" = Table.SelectColumns(#"Added Custom", {"Custom"}), 
  #"Expanded Custom" = Table.ExpandTableColumn(
    #"Removed Other Columns", 
    "Custom", 
    {"Number", "Index", "IndexNb"}, 
    {"Custom.Number", "Custom.Index", "Custom.IndexNb"}
  ), 
  #"Sorted Rows" = Table.Sort(#"Expanded Custom", {{"Custom.Index", Order.Ascending}}), 
  #"Added Conditional Column" = Table.AddColumn(
    #"Sorted Rows", 
    "Flag", 
    each if [Custom.Number] = 8 and [Custom.IndexNb] = 1 then [Custom.Index] else 0
  ), 
  #"Removed Top Rows" = Table.Skip(
    #"Added Conditional Column", 
    List.Max(#"Added Conditional Column"[Flag])
  ), 
  #"Removed Other Columns1" = Table.SelectColumns(#"Removed Top Rows", {"Custom.Number"}), 
  #"Filtered Rows" = Table.SelectRows(#"Removed Other Columns1", each [Custom.Number] > 8)
in
  #"Filtered Rows"

let
  Bron = Excel.CurrentWorkbook(){[Name = "Tabel1"]}[Content], 
  TypeChange = Table.TransformColumnTypes(Bron, {{"Number", Int64.Type}}), 
  AddCol1 = Table.AddColumn(TypeChange, "Is8", each if [Number] = 8 then 1 else 0), 
  AddCol2 = Table.AddColumn(AddCol1, "Total8", each List.Sum(AddCol1[Is8])), 
  Index = Table.AddIndexColumn(AddCol2, "Index", 0, 1, Int64.Type), 
  Addcol3 = Table.AddColumn(Index, "RunningTotal", each List.Sum(List.FirstN(Index[Is8], [Index]))), 
  TypeChanged = Table.TransformColumnTypes(Addcol3, {{"RunningTotal", Int64.Type}}), 
  NulltoNull = Table.ReplaceValue(TypeChanged, null, 0, Replacer.ReplaceValue, {"RunningTotal"}), 
  CleanCols = Table.RemoveColumns(NulltoNull, {"Index", "Is8"}), 
  FilterCol = Table.AddColumn(
    CleanCols, 
    "FilterCol", 
    each if [RunningTotal] = [Total8] then "Keep" else "Remove"
  ), 
  Removerows = Table.SelectRows(FilterCol, each ([FilterCol] = "Keep")), 
  CleanTable = Table.RemoveColumns(Removerows, {"Total8", "RunningTotal", "FilterCol"}), 
  Greaterthan8 = Table.SelectRows(CleanTable, each [Number] > 8)
in
  Greaterthan8